Script: New Voice Control Commands File

Here is an AppleScript script tool (macOS) for generating a new blank Voice Control commands file containing a single placeholder (line 7-8) that you can replace with your own command(s).

The generated file has a “.voicecommands” file extension and is saved in standard Apple XML property list format.

New Voice Control Commands File (XML Property List)
Copy

<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE plist PUBLIC "-//Apple//DTD PLIST 1.0//EN" "http://www.apple.com/DTDs/PropertyList-1.0.dtd">
<plist version="1.0">
<dict>
	<key>CommandsTable</key>
	<dict>
		<key>REPLACE THIS KEY AND VALUE WITH YOUR COMMAND</key>
		<dict/>
	</dict>
	<key>ExportDate</key>
	<real>672051057.85952532</real>
	<key>SystemVersion</key>
	<dict>
		<key>ProductBuildVersion</key>
		<string>21E230</string>
		<key>ProductCopyright</key>
		<string>1983-2022 Apple Inc.</string>
		<key>ProductName</key>
		<string>macOS</string>
		<key>ProductUserVisibleVersion</key>
		<string>12.3</string>
		<key>ProductVersion</key>
		<string>12.3</string>
		<key>iOSSupportVersion</key>
		<string>15.4</string>
	</dict>
</dict>
</plist>

Property List Editor and Tools

Here is the script code written in AppleScriptObj-C:

AppleScript Script: New Voice Control Commands File
Copy

use AppleScript version "2.4"
use framework "Foundation"
use scripting additions

-- classes, constants, and enums used
property NSPropertyListBinaryFormat_v1_0 : a reference to 200
property NSPropertyListSerialization : a reference to current application's NSPropertyListSerialization
property NSString : a reference to current application's NSString
property NSDictionary : a reference to current application's NSDictionary
property NSMutableDictionary : a reference to current application's NSMutableDictionary
property NSNumberFormatter : a reference to current application's NSNumberFormatter

set thePropertyListFilePath to POSIX path of (choose file name with prompt "Name and location for the new file:" default name "new-command-set.voicecontrolcommands")
if thePropertyListFilePath does not end with ".voicecontrolcommands" then
	set thePropertyListFilePath to thePropertyListFilePath & ".voicecontrolcommands"
end if

set systemInfoPath to "/System/Library/CoreServices/SystemVersion.plist"
set systemInfoDict to NSDictionary's dictionaryWithContentsOfFile:systemInfoPath
set ProductBuildVersion to systemInfoDict's valueForKey:"ProductBuildVersion"
set ProductCopyright to systemInfoDict's valueForKey:"ProductCopyright"
set ProductName to systemInfoDict's valueForKey:"ProductName"
set ProductUserVisibleVersion to systemInfoDict's valueForKey:"ProductUserVisibleVersion"
set ProductVersion to systemInfoDict's valueForKey:"ProductVersion"
set iOSSupportVersion to systemInfoDict's valueForKey:"iOSSupportVersion"

set exportDateString to generateAbsoluteTimeID()
set masterDict to NSMutableDictionary's new()
set commandsDict to NSMutableDictionary's new()
tell masterDict to setObject:commandsDict forKey:"CommandsTable"
set entryDict to NSMutableDictionary's new()
tell commandsDict to setObject:entryDict forKey:"REPLACE THIS KEY AND VALUE WITH YOUR COMMAND"
tell masterDict to setObject:(exportDateString as real) forKey:"ExportDate"
set systemEntriesDict to NSMutableDictionary's new()
tell systemEntriesDict to setObject:ProductBuildVersion forKey:"ProductBuildVersion"
tell systemEntriesDict to setObject:ProductCopyright forKey:"ProductCopyright"
tell systemEntriesDict to setObject:ProductName forKey:"ProductName"
tell systemEntriesDict to setObject:ProductUserVisibleVersion forKey:"ProductUserVisibleVersion"
tell systemEntriesDict to setObject:ProductVersion forKey:"ProductVersion"
tell systemEntriesDict to setObject:iOSSupportVersion forKey:"iOSSupportVersion"
tell masterDict to setObject:systemEntriesDict forKey:"SystemVersion"

writeAsPropertyList(masterDict, thePropertyListFilePath)

display dialog "The new Voice Control commands file has been created." buttons {"Done", "Show in Finder"} default button 2
set chosenAction to the button returned of the result
if chosenAction is "Show in Finder" then
	tell application "Finder"
		activate
		reveal (thePropertyListFilePath as POSIX file)
	end tell
else if chosenAction is "Open in Editor" then
	set editingApplication to (choose application with prompt "Choose application to edit the voice commands file:")
	tell editingApplication
		activate
		open (thePropertyListFilePath as POSIX file)
	end tell
end if

on writeAsPropertyList(theRecord, thePath)
	set thePath to NSString's stringWithString:thePath
	set thePath to thePath's stringByExpandingTildeInPath()
	set savingFormat to NSPropertyListBinaryFormat_v1_0
	set theData to NSPropertyListSerialization's dataWithPropertyList:theRecord format:savingFormat options:0 |error|:(missing value)
	theData's writeToFile:thePath atomically:true
	return result -- so we can see if it saved
end writeAsPropertyList

on generateAbsoluteTimeID()
	## 669490008.038141
	set currentAbsoluteTime to current application's CFAbsoluteTimeGetCurrent()
	set fmtr to NSNumberFormatter's new()
	fmtr's setFormat:"#.#########"
	set exportDateString to NSString's stringWithFormat_("%@", fmtr's stringFromNumber:currentAbsoluteTime) as string
	if length of exportDateString is not 23 then
		repeat until length of exportDateString is 18
			set exportDateString to exportDateString & (random number from 1 to 9) as string
		end repeat
	end if
	return exportDateString
end generateAbsoluteTimeID